Squirrel

Hi all,
I'm a newbie of using squirrel script. It's a powerful script lang. I like it very much. But I have a problem about delegation introduced in the document.

// original code snippet in the doc
Entity <- {}

function Entity::DoStuff()
{
    ::print(_name);
}

local newentity = {
    _name="I’m the new entity"
}
newentity.setdelegate(Entity)
newentity.DoStuff();

It will print “I’m the new entity”, but when I assign a new variable also named "_name", it just does not work as expected.

local _name = "outside scope"

Entity <- {}
function Entity::DoStuff()
{
    ::print(_name);
}

local newentity = {
    _name="I’m the new entity"
}
newentity.setdelegate(Entity)
newentity.DoStuff();

is there anything wrong about it? or I just misunderstand about "Delegation" in squirrel? any suggestions about how to write it correctly in this situation?

Thanks

this seems to work (on 3.0 beta 1)

local _name = "outside scope"

Entity <- {}
function Entity::DoStuff()
{
    ::print(this._name);
}

local newentity = {
    _name="I’m the new entity"
}
newentity.setdelegate(Entity)
newentity.DoStuff();

but the manual does not explain why local variables take precedence over the table slots?

OK the manual does say

"Squirrel first checks if an identifier is a local variable (function arguments are local variables) if not it checks if it is a member of the environment object (this). "

but do "local variables" include these in the outer scopes?

Hope Alberto can respond to this...


seems the reasonable way to determine the variable scope should be


in terms of priority,

local variables of the current block
function parameters
slots of "this" (the current environment)
local variables of the outter scopes


else it may be better just to demand that, in a function body,

all access to slots of the current environment must be prefixed with "this."
and all global variables must be prefixed with "::"

if that helps with performance people may be willing to accept?

the look up of a symbol is in this order

1)local variables (function parameters are local variables)
2)free variables(local from outer scope)
3)constants
4)slot in the 'this' object
5)if 4 fails at runtime it falls back the root table

if the symbol is prefixed with :: then it goes straight to the root table

if the symbol is prefixed with 'this.' then it goes straight to the this slots

Alberto

I guess some people may expect Step 4 go to between Step 1 and Step 2...

That seems to me to be more natural...

Of course based on your description the explict prefixes should be faster and may be a reason for people to use them.

It works. Thank you, Alberto and atai.
 it's reasonable to use the explicit prefixes. and now I understand why the examples in the document usually use explicit prefixes. I like the style of squirrel.
Thanks for replying and detailed explanation.

Andrews.